07｜六行代码进入保护模式
你好，我是闪客。
这一讲我们要探讨的问题是，操作系统如何使 CPU 进入保护模式。保护模式虽然较为复杂，但仅仅是把模式切换过来只需要六行代码。
上一讲的最后，我们的内存布局变成了后面这样：
这仅仅是进入保护模式前准备工作的其中一个，我们接着往下看。
打开 A20 地址线
下面的代码仍然是 setup.s 中的。
mov al,#0xD1 ; command write
out #0x64,al
mov al,#0xDF ; A20 on
out #0x60,al
这段代码的意思是打开 A20 地址线。到底什么是 A20 地址线呢？
简单来说，这一步就是为了突破地址信号线 20 位的宽度，变成 32 位可用。这是由于 8086 CPU 只有 20 位的地址线，所以如果程序给出 21 位的内存地址数据，那多出的一位就被忽略了。
我举个例子，你更容易理解。比如如果经过计算得出一个内存地址为：
1 0000 00000000 00000000
那实际上内存地址相当于 0，因为高位的那个 1 被忽略了，溢出了地址线。
当 CPU 到了 32 位时代之后，由于要考虑兼容性，还必须保持一个只能用 20 位地址线的模式，所以如果你不手动开启的话，即使地址线已经有 32 位了，仍然会限制只能使用其中的 20 位。
简单么？我们继续往下看。接下来这段代码，我建议你完全不用看，毕竟 Linus自己都注释说过“这是一段不得不做，又一点意思也没有的代码”。
什么？你觉得剧情不能快进，为了防止你心里一直记挂它，我把这部分截出来说道说道。这样以后我说完全不用看的代码时，你就真的可以放宽心完全不看了。
; well, that went ok, I hope. Now we have to reprogram the interrupts :-(
; we put them right after the intel-reserved hardware interrupts, at
; int 0x20-0x2F. There they won't mess up anything. Sadly IBM really
; messed this up with the original PC, and they haven't been able to
; rectify it afterwards. Thus the bios puts interrupts at 0x08-0x0f,
; which is used for the internal hardware interrupts as well. We just
; have to reprogram the 8259's, and it isn't fun.
mov al,#0x11 ; initialization sequence
out #0x20,al ; send it to 8259A-1
.word 0x00eb,0x00eb ; jmp $+2, jmp $+2
out #0xA0,al ; and to 8259A-2
.word 0x00eb,0x00eb
mov al,#0x20 ; start of hardware int's (0x20)
out #0x21,al
.word 0x00eb,0x00eb
mov al,#0x28 ; start of hardware int's 2 (0x28)
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0x04 ; 8259-1 is master
out #0x21,al
.word 0x00eb,0x00eb
mov al,#0x02 ; 8259-2 is slave
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0x01 ; 8086 mode for both
out #0x21,al
.word 0x00eb,0x00eb
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0xFF ; mask off all interrupts for now
out #0x21,al
.word 0x00eb,0x00eb
out #0xA1,al
这里是对可编程中断控制器 8259 芯片进行的编程。
因为中断号是不能冲突的， Intel 把 0 到 0x19 号中断都作为保留中断，比如 0 号中断就规定为除零异常，软件自定义的中断都应该放在这之后，但是 IBM 在原 PC 机中搞砸了，跟保留中断号发生了冲突，以后也没有纠正过来。所以，我们得重新对其进行编程，不得不做，却又一点意思也没有。
上面说的细节你都记不住？没关系，不必在意，最后你只要知道重新编程之后，8259 这个芯片的引脚与中断号的对应关系，变成了后面这样：
也就是说，假如我们按下键盘，将会从 8259A 芯片的 IRQ1 引脚处发起电信号，而又因为我们对其进行了编程，IRQ1 引脚处的电信号将会转化为给 CPU 发起的一个 0x21 号中断。所以，结论就是按下键盘会触发一个 0x21 号中断，这就是上面这一大坨代码的作用。
完成切换模式的关键一步
好了，接下来的一步，就是真正切换模式的一步了，从代码上看就三行：
mov ax,#0x0001 ; protected mode (PE) bit
lmsw ax ; This is it;
jmpi 0,8 ; jmp offset 0 of segment 8 (cs)
前两行代码，将 cr0 这个寄存器的位 0 置 1，模式就从实模式切换到保护模式了。可以看看后面的示意图：
结合图示我们发现，真正的模式切换十分简单，只是更改一个寄存器的一位而已。不过一旦更改这个位，CPU 的很多逻辑将会变得完全不同，就比如上一讲说的物理地址的转化过程。
再往后，又是一个段间跳转指令 jmpi，后面的 8 表示 cs 寄存器的值，0 表示 ip 寄存器的值，换一种伪代码表示就等价于：
cs = 8
ip = 0
请注意，此时已经是保护模式了，之前也说过，保护模式下内存寻址方式变了，段寄存器里的值被当作零段选择子。
回顾下段选择子的模样：
8 用二进制表示就是：
00000,0000,0000,1000
对照上面段选择子的结构，可以知道描述符索引值是 1，也就是CPU要去全局描述符表（gdt）中找索引 1 的描述符。
还记得上一讲中的全局描述符的具体内容么？
gdt:
.word 0,0,0,0 ; dummy
.word 0x07FF ; 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 ; base address=0
.word 0x9A00 ; code read/exec
.word 0x00C0 ; granularity=4096, 386
.word 0x07FF ; 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 ; base address=0
.word 0x9200 ; data read/write
.word 0x00C0 ; granularity=4096, 386
我们说了，第 0 项是空值，第一项被表示为代码段描述符，是个可读可执行的段，第二项为数据段描述符，是个可读可写段，不过他们的段基址都是 0。
所以，这里取的就是这个代码段描述符，段基址是 0，偏移也是 0，那加一块就还是 0 。那么最终这个跳转指令，就是跳转到内存地址的 0 地址处，开始执行。
零地址处是什么呢？回顾之前的内存布局图，就是操作系统全部代码的 system 这个大模块。
那system 模块怎么生成的呢？由 Makefile 文件可知，这是由 head.s 和 main.c 以及其余各模块的操作系统代码合并来的，你可以这样理解：这里是操作系统的全部核心代码编译后的结果。
tools/system: boot/head.o init/main.o \
$(ARCHIVES) $(DRIVERS) $(MATH) $(LIBS)
$(LD) $(LDFLAGS) boot/head.o init/main.o \
$(ARCHIVES) \
$(DRIVERS) \
$(MATH) \
$(LIBS) \
-o tools/system > System.map
哇，有没有感觉，之前的内容已经全都串起来了！
接下来，我们就要重点阅读 head.s 了，因为它是 system 模块的最开头的代码，零地址处的代码，就是 head.s 里的第一行代码！在那里，操作系统真正秀操作的地方，才刚刚开始！
总结时刻
这一讲，我们用六行代码让 CPU 进入了保护模式，并且跳转到零地址处，也就是 system 模块这里来运行。同时，我们还粗略地看了一下为 8259A 芯片写的代码，找了找中断的感觉。
好，我是闪客。欲知后事如何，且听下回分解。